PT2260 PIC16F628 pir dedektörlü telefon aramalı alarm

PT2260 PIC16F628A Telefon arama modüllü pir dedektörlü kapı anahtarlı uzaktan kumandalı alarm devresi hazırlayan onurbilke tüm kaynak dosyalar bulunmakta değişik çok fonksiyonlu bir alarm devresi alarm devreleri ile ilgilenen bir çok kişi için iyi bir örnek özellikle PIR dedektör olması çok iyi Emeği geçen hazırlayan kişilere teşekkürler

Sistem PIR Dedektörü Kapı Anahtarı Uzaktan Kumanda Ve Telefon Arama Modülünden Oluşmaktadır. Uzaktan Kumanda Olarak İçerisinde PT2260 Entegresi Olan Herhangi Bir Uzaktan Kumanda Kullanılabilir. Bu Tür Kumandaları Ankara Konya Sokaktan Temin Edebilirsiniz. Telefon Modülü Olarak CODESEC PSTN VOICE DIALER Kullanılmıştır. (www.codesectech.com) Yine Bu Ve Buna Benzer Modülleri Ankara Konya Sokaktan Temin Edebilirsiniz. Bu Modül Sinyal Ucuna (-) Verdiğimiz Zaman Devreye Giriyor.

Alarm Kumanda Yoluyla Devreye Sokulduğu Zaman Kapı Veya PIR dan Gelecek Sinyali Bekler. Beklenen Sinyal Geldiği Zaman Telefon Arama Modülü Ve Siren Devreye Girer. Kapı Kapatılırsa Veya Hareket Kesilirse Bile Siren Sizin Belirttiğiniz Süre Boyunca Çalacaktır. Sistem Tekrar Kumanda Yardımıyla Devreden Çıkartılabilir. Elektrikler Gidip Gelse Dahi Sistem Kaldığı Konumdan Çalışmaya Devam Eder. Kapı Anahtarı İçin Bilgiğimiz Herhangi Bir Anahtar Kullanabiliriz.

NOT:Devrenin Açık Şeması Baskı Devresi (Proteus) Pic Basic PRO İle Yazılmış Kodları Ve Resimleri Ektedir. Baskı Devre Üzerindeki Transistörlerin Bağlantısı Yanlış Olabilir Transistörleri Takarken Açık Şemaya Dikkat Ediniz

Sistem Tamamen Kendi Tasarımım Olup Sorunsuz Çalışmaktadır.

Yazılım (pbp)

'****************************************************************
'*  Name    : UNTITLED.BAS                                      *
'*  Author  : [ONUR BİLKE]                                      *
'*  Notice  : Copyright (c) 2008 [DREAM]                        *
'*          : All Rights Reserved                               *
'*  Date    : 20.07.2008                                        *
'*  Version : 1.0                                               *
'*  Notes   :                                                   *
'*          :                                                   *
'********************
CMCON=7

TrisA=%01001111
TrisB=%10000001

PortA=0
PortB=0

Tel var PortA.4
Role var PortB.4
Led var PortB.3
PIR var PortB.7
Kap var PortA.6
Buzer var PortB.1
VT var PortB.0
D0 var PortA.0
D1 var PortA.1
D2 var PortA.2
D3 var PortA.3

i var byte
j var word
k var word
Bekleme Var Word
Sayac var word
Alarm var bit
Okunan var byte

Alarm=0
Bekleme=120 'Saniye /Kapı Kapatılsa Veya Sensör Hareket Algılamasa Bile Alarmın Çalma Süresi
Sayac=0
'*************************
for i=0 to 59 'PIR Sensörü Isınana Kadar Bekle
    pause 1000
next
'*************************
read 1,Okunan 'Elektrik Kesilip Geri Gelirse Kaldığın Yerden Devam Et
if Okunan=1 then
    Alarm=1
    high led
else
    Alarm=0
    low led
endif
'************************
high buzer 'Sistemin Devrede Olduğunu Ses Çıkararak Bildir
pause 100
low buzer
'************************
Basla:
    gosub Kumanda_Oku
    
    if Alarm=1 then
        Sayac=0
        Gosub Kontrol    
    else
        low tel
        low role
        Sayac=0
    endif    
goto Basla
'**********************
Kontrol:
    if PIR=1 or Kap=0 then
        gosub Kumanda_OKU
        high role
        high tel
    else
        while Sayac<=Bekleme*10 and Alarm=1
            gosub Kumanda_Oku
            pause 100
            Sayac=Sayac+1
            goto Kontrol
        wend
        low role
    endif
return
'********************
Kumanda_Oku:
    if Vt=1 then
    
        if D0=1 and D1=1 and D2=1 and D3=1 then toggle AlarM
    
        if Alarm=1 then 
            Gosub Alarm_Ac
        else
            gosub Alarm_Kapat
        endif
    
    endif
return
'*************
Alarm_Ac:
    high led
    high Buzer
    pause 800
    low Buzer
    write 1,1
return
'***************
Alarm_Kapat:
    for i=0 to 2
        low led
        high buzer
        pause 100
        low buzer
        pause 100
    next
    write 1,0
return
'***************
End