Basit Siyah Çizgi Takip Eden Robot Projesi

Robot devresi üzerinde fazla malzeme yok basit bir yerleşim var hazır bir oyuncak arabanın mekanik kısmı kullanılmış motor fazla güç çekmediği için iki adet 2sc2001 transistör ile sürülmüş kontrol ünitesi pic16f84 üzerine kurulu

A line tracer is a line that runs on a line drawn in black (7 m / m wide) by illuminating it with infrared rays, etc., and controlling the left and right motors.
This time, we used a 3-volt wheat ball instead of infrared rays to illuminate the line, shining ordinary light, and using a CDS with a diameter of 5 m / m (in Akizuki) for the sensor.

When the CDS hits the line, it sends an OFF signal, and when it goes off the line, it sends an ON signal to RA1 and RA2 of PIC port A, and controls RB4 and RB6 of port B to turn on the motor of the twin motor gearbox (TAMIYA). It turns off. The LED indicates the status.

The software is very ordinary, but RB0 on ​​port B has an external interrupt. When an interrupt occurs, the motor stops temporarily (about 30 seconds), and the LEDs blink alternately to indicate that the interrupt operation has started. Also, the oscillating sound signal is output from RB7 of port B. These are not wired, but half of the board is a circled dot board, so you can experiment with your favorite circuits later. For example, interrupting with voice or light.

HEX dosyası için derleme yaparken yapılandırma aşağıda ki gibi olacak

.OSC RC; Osilatör tipi: RC

PWRT ON; Power-up timer: ON

.WDT OFF; Watchdog timer: OFF

.PROTECT OFF; Kod koruması: KAPALI

Takip Eden Robot Assembly Kaynak Kodu

	LIST	P=16F84,R=DEC

INTCON	EQU	H'B'

STATUS	EQU	3

PG	EQU	5

PORTB	EQU	6

PORTA	EQU	5

TRISA	EQU	H'85'

TRISB	EQU	H'86'

PORTA_IN	EQU	H'11'	

WORK_REG	EQU	H'12'

WORK_STATE	EQU	H'13'

COUNTER		EQU	H'14'

COUNTER2 	EQU	H'15'

COUNTER3 	EQU	H'16'

COUNTER4 	EQU	H'17'



;**********************************

	ORG	0

	GOTO	START

	ORG	4

	GOTO	INT





;**********************************

;

;***********************************



START	BSF	STATUS,PG

	MOVLW	B'00110'

	MOVWF	TRISA

	MOVLW	B'00000001'

	MOVWF	TRISB

	BCF	STATUS,PG

	MOVLW	B'10010000'

	MOVWF	INTCON

	CLRF	PORTB



;************************************

;

;************************************



MAIN	MOVF	PORTA,0

	MOVWF	PORTA_IN

	MOVLW	B'00110'

	ANDWF	PORTA_IN,1

	MOVLW	B'00000'

	SUBWF	PORTA_IN,0

	BTFSC	STATUS,2

	GOTO	STR



	MOVLW	B'00010'

	SUBWF	PORTA_IN,0

	BTFSC	STATUS,2

	GOTO	RSTP



	MOVLW	B'00100'

	SUBWF	PORTA_IN,0

	BTFSC	STATUS,2

	GOTO	LSTP



	MOVLW	B'00110'

	SUBWF	PORTA_IN,0

	BTFSC	STATUS,2

	GOTO	STP



	GOTO	MAIN

	

;**************************************

;

;**************************************

STR	MOVLW	B'01011010'

	MOVWF	PORTB	

	GOTO	MAIN



RSTP	MOVLW	B'00011000'

	MOVWF	PORTB	

	GOTO	MAIN



LSTP	MOVLW	B'01000010'

	MOVWF	PORTB	

	GOTO	MAIN



STP	MOVLW	B'00000000'

	MOVWF	PORTB

	GOTO	MAIN

	



;****************************************

;	Interrupt processing

;*****************************************

INT	MOVWF	WORK_REG

	SWAPF	STATUS,W

	MOVWF	WORK_STATE

	BCF	INTCON,1

	

	CALL	SAB_TAIM



	SWAPF	WORK_STATE,W

	MOVWF	STATUS

	SWAPF	WORK_REG,F

	SWAPF	WORK_REG,W

	RETFIE





;******************************************

;	Interrupt subroutine

;******************************************

SAB_TAIM	

	CLRF	PORTB

	MOVLW	20

	MOVWF	COUNTER2



LOOP

	BSF	PORTB,1

	MOVLW	150

	MOVWF	COUNTER3

DLY1	BSF	PORTB,7

	GOTO	$+1

	GOTO	$+1

	GOTO	$+1

	GOTO	$+1

	GOTO	$+1

	GOTO	$+1

	BCF	PORTB,7

	GOTO	$+1

	GOTO	$+1

	GOTO	$+1

	GOTO	$+1

	GOTO	$+1

	GOTO	$+1

	DECFSZ	COUNTER3,1

	GOTO	DLY1



	BCF	PORTB,1

	BSF	PORTB,3



	MOVLW	150

	MOVWF	COUNTER4

DLY2	BSF	PORTB,7

	GOTO	$+1

	GOTO	$+1

	GOTO	$+1

	GOTO	$+1

	GOTO	$+1

	GOTO	$+1

	BCF	PORTB,7

	GOTO	$+1

	GOTO	$+1

	GOTO	$+1

	GOTO	$+1

	GOTO	$+1

	GOTO	$+1

	DECFSZ	COUNTER4,1

	GOTO	DLY2

	BCF	PORTB,3

	DECFSZ	COUNTER2,1



	GOTO	LOOP

	

	RETURN





;*******************************************

	END

;*******************************************

Kaynak site: web1.incl.ne.jp/nisimo/rain.html